Sorting and Filtering Functions

Worksheet Functions

Excel Functions: Excel 2021 and 365 provide the following sorting and filtering array functions.

SORT(R1, sortcol, order): returns an array with the data in R1 in sorted order based on the elements in column sortcol (the “sort key”) of R1 (default 1). If order = 1 (default), the sort is in ascending order; if order = -1, the sort is in descending order.

UNIQUE(R1): returns an array with the unique entries in the column array R1.

FILTER(R1, criteria, if_empty): returns an array with the subset of the data in R1 that meets the criteria; if none of the data meets the criteria then the if_empty value is returned (if omitted then a #CALC! error value is returned)

SORT Function

E.g. to sort the data in Figure 1 of Sorting and Filtering and place the output in the range starting in cell F4, insert the dynamic array formula =SORT(A4:D12,4) in cell F4 and press Enter. The result is shown in Figure 1.

Figure 1 – SORT function

UNIQUE Function

Placing the dynamic array formula =UNIQUE(D4:D12) in cell K4 returns the output shown in column K of Figure 2. Placing the dynamic array formula =SORT(UNIQUE(D4:D12)) in cell M4 returns the output shown in column M of Figure 2.

Figure 2 – UNIQUE function

FILTER Function

We can place the formula

=FILTER(A4:D12, (D4:D12>=35000)*(D4:D12<=45000),””)

in cell O4 to extract all the people from Figure 1 who have income between 35,000 and 45,000 inclusive, as shown in Figure 3.

Figure 3 – FILTER function (AND criteria)

Note that we use “*” to specify that two criteria must both hold (i.e. as an AND of the two criteria). We can use “+” to specify that one of two criteria must hold (i.e. as an OR of the two criteria). We can use a combination of one or more “+” and “*” to specify more involved criteria.

We can place the formula

=FILTER(A4:D12,(D4:D12>40000)+(B4:B12=“F”),””)

in cell T4 to extract all the entries from Figure 1 of people who have income that exceeds 40,000 or are female, as shown in Figure 4.

Figure 4 – FILTER function (OR criteria)

Note that the criteria expression must refer to a complete row or column or subrange of the range specified in the first argument in FILTER. Thus, while you can use =FILTER(A4:D12,D4:D12>40000) you can’t use =FILTER(A4:D12,D4:D10>40000).

SORTBY Function

Excel Function: Excel 2021 and 365 also provide the following enhanced sorting function:

SORTBY(R1, sortcol1, order1, sortcol2, order2, …): returns an array with the data in R1 in sorted order based on the elements in the column array sortcol1 (the “sort key”) of R1 (default 1). If order1 = 1 (default), the sort is in ascending order; if order1 = -1, the sort is in descending order. If specified via sortcol2 you can also use a secondary sort key (and additional sort keys  sortcol3, etc. if you like).

Whereas the sortcol argument in SORT is the index to a column in R1, in SORTBY sortcol1 is a column array or range that may or may not be part of R1, although it must have the same number of rows as R1.

E.g. if you want to sort the data in Figure 1 by income and then by the person’s name (as in Figure 5 of Sorting and Filtering), you can enter the formula =SORTBY(A4:D12,D4:D12,1,A4:A12,1) in cell Y4 and press Enter, as shown in Figure 5.

Figure 5 – SORTBY function

If you want to sort first by age in ascending order and then by income in descending order but you don’t want the incomes to appear in the output, you can place the formula =SORTBY(A4:C12,C4:C12,1,D4:D12,-1) in cell AD4 and press Enter, as shown in Figure 6.

Figure 6 – Another SORTBY example

Examples Workbook

Click here to download the Excel workbook with the examples described on this webpage.

References

Mellor, L. (2020) Sort and filter using dynamic array functions in Microsoft Excel
https://www.laramellortraining.co.uk/how-to-sort-and-filter-using-dynamic-array-functions-in-microsoft-excel

Stack Overflow (2021) Sortby function combined with Unique combined with filter functions
https://stackoverflow.com/questions/68246608/sortby-function-combined-with-unique-and-filter-functions-how-to-use-it-correcl

Proctor, M. (2020) SORTBY function in Excel. Excel off the Grid
https://exceloffthegrid.com/sortby-function-in-excel/